СПИСОК ИСПОЛЬЗОВАННЫХ ИСТОЧНИКОВ

[1] Портативный прибор для неинвазивного измерения параметров функционирования состояния пациентов (Монитор пациента) / Технический отчет по проекту В-371 МНТЦ. - М. : 2002. - 132 с.

[2] ГОСТ 21829-76 Система «человек-машина». Кодирование зрительной информации. Общие эргономические требования.

[3] Ломова, Б. Основы инженерной психологии / Б. Ломова. - М. : Высшая школа, 1986. - 448 с.

[4] Контроллер дисплея - Класс 6G09G 5/06, JP2983579 B2 4021893A, Изобретения стран мира, Выпуск 96, МПК G 09, 2000, №12, 28 с.

[5] Устройство дисплея подвижного изображения и внешние запоминающие устройства, используемое для него - Класс 6G06T 1/00, 1/60, RU 2106012 от 04.10.91, Изобретения. Официальный бюллетень Российского агентства по патентам и товарным знакам, М.1998, №6, 288 с.

[6] Графический дисплей - Класс 7G09G 5/34, JP 3226939 B2, Изобретения стран мира, Выпуск 96, МПК G 09, 2002, №11, 38 с.

[7] Устройство для частичной прокрутки изображения на экране дисплея - Класс 7G09G 5/34, JP 3196848 B2, Изобретения стран мира, Выпуск 96, МПК G 09, 2002, №8, 35 с.

[8] Схема для вычисления адреса памяти - Класс 7G09G 5/34, JP 3124166 B2 7199901 A от 28.12.1993, Изобретения стран мира, Выпуск 96, МПК G 09, 2002, №1, 38 с.

[9] Павлов, С. П. Охрана труда в приборостроении : учебник для вузов / С.П. Павлов, З.И. Губонина. - М. : ВШ, 1986. -215 с.

[10] СанПиН 9-80 РБ 98.

[11] СН 9-86 РБ 98

[12] Прикроватный монитор «Тритон» для системы централизованного мониторинга - [Электронный ресурс]. - Электронные данные. - Режим доступа: http://ekoholding.ru/index.php?page=text&url=monitors#monitoring SCM/

[13] Монитор HEWLETT PACKARD Viridia M3 - [Электронный ресурс]. - Электронные данные. - Режим доступа : http://www.8a.ru/print/12271.php/

[14] Старова, Л. Технико-экономическое обоснование дипломных проектов: Метод, пособие для студ. всех спец. БГУИР дневной и заочной форм обучения : в 4 ч. Ч. 3. Методика расчета экономической эффективности инновационных технологий / Л. Старова. - Мн.: БГУИР, 2004. - 64 с.

ПРИЛОЖЕНИЯ

ПРИЛОЖЕНИЕ А

Фрагмент программы для вывода числовых данных

.DSEG

;******************************************************

CurrFont: .BYTE 22 ;Текущий шрифт

CurrFontCX: .BYTE 1 ;Ширина символов шрифта

Counter: .BYTE 1

;Числовые каналы (смещения):

.EQU NumYb = 0 ;Координата верхней строки (2 байта)

.EQU NumYbH = 1 ;Координата верхней строки (старш. байт)

.EQU NumXb = 2 ;Координата правого столбца (2 байта)

.EQU NumXbH = 3 ;Координата правого столбца (старш. байт)

.EQU NumData = 4 ;Выводимые данные (2 байта)

.EQU NumDataH = 5 ;Выводимые данные (старш. байт)

.EQU NumColor = 6 ;Цвет символов

.EQU NumFont = 7 ;Шрифт

.EQU NumFormat = 8 ;Формат вывода (LEFT/RIGHT|ZEROS/NOZRS)

.EQU LEFT = 0b01 ; Выравнивание влево

.EQU RIGHT = 0b00 ; Выравнивание вправо

.EQU ZEROS = 0b10 ; Писать незначащие 0

.EQU NOZRS = 0b00 ; Не писать незначащие 0

.EQU NumDig = 9 ;Количество цифр (100 - 3,10 - 2)

.EQU NumStatus = 10 ;Состояние канала (1-требуется перерисовка)

.EQU NUM_DAT_CH = 8 ;Количество каналов

.EQU BYTE_DAT_CH = 12 ;Количество данных/канал

NumChanals: .BYTE NUM_DAT_CH*BYTE_DAT_CH ;область данных каналов

;-----------------------------------------------------------

.CSEG

START:

loop1:

rcall DrawAllNums

rjmp loop1

;Подпрограмма перерисовки числовых каналов.

DrawAllNums:

push r0

push r2

push r3

push r4

push r5

push r6

push r7

push r8

push r9

push r10

push r16

push r17

push YL

push YH

ldi YL,low(NumChanals) ;Y - 1-й канал

ldi YH,high(NumChanals)

clr r17 ;Номер канала

nxtNum:ldd r16,Y+NumStatus

tst r16

breq skipNum

ldd r0,Y+NumFont

call LoadFont ;Загрузка шрифта

ldd r2,Y+NumDig

ldd r3,Y+NumFormat

ldd r4,Y+NumData

ldd r5,Y+NumDataH

ldd r6,Y+NumXb

ldd r7,Y+NumXbH

ldd r8,Y+NumYb

ldd r9,Y+NumYbH

ldd r10,Y+NumColor

call PrintDigit ;Вывод числа

clr r16

std Y+NumStatus,r16

skipNum:

adiw YL,BYTE_DAT_CH

inc r17

cpi r17,NUM_DAT_CH

brne nxtNum

pop YH

pop YL

pop r17

pop r16

pop r10

pop r9

pop r8

pop r7

pop r6

pop r5

pop r4

pop r3

pop r2

pop r0

ret

;------------------------------------------------------

;Подпрограмма вывода числа

;r5:r4 - число

;r2 - колич-во разрядов (100-три, 10-два)

;r3 - выравнивание (бит 1: 1-влево,0-вправо)

; - незначащие 0 (бит 2: 1-писать,0-не писать)

;r7:r6 - коорд. левого столбца (Xleft)

;r9:r8 - коорд. верхней строки (Ytop)

;r10 - цвет (COLOR)

PrintDigit:

push XleftH

push Xleft

push r19

push r18

push r17

push r16

push r1

push r0

mov r17,r2 ;Делитель

clr r1 ;Кол-во пробелов после

NxtDig:clr r0 ;Счетчик-цифра

movw r18,r4

lp1: sub r18,r17

sbci r19,0

brlt PrCh

movw r4,r18

inc r0

rjmp lp1

PrCh:

tst r0 ;Цифра - 0?

brne cnt1

sbrc r3,1 ;Писать незнач.0?

rjmp cnt2 ;Писать!

sbrc r3,0 ;Писать пробел?

rjmp NPr ;Не писать!

ldi r16,10

mov r0,r16

rjmp cnt2

NPr:inc r1

rjmp NoPrn ;Пропустить вывод

cnt1:ldi r16,0b10 ;Начать писать нули

or r3,r16

cnt2:

rcall PrintChar

lds r16,CurrFontCX ;Нов. координаты симв

add Xleft,r16

ldi r16,0

adc XleftH,r16

NoPrn:

cpi r17,100

brlt div10

ldi r17,10

jmp NxtDig

div10:cpi r17,10

brlt div1

ldi r17,1

jmp NxtDig

div1:;Дописать пробелы

ldi r16,10

mov r0,r16

nxtSp:tst r1

breq retn

dec r1

rcall PrintChar

lds r16,CurrFontCX ;Нов. координаты симв

add Xleft,r16

ldi r16,0

adc XleftH,r16

rjmp nxtSp

retn:pop r0

pop r1

pop r16

pop r17

pop r18

pop r19

pop Xleft

pop XleftH

ret

ПРИЛОЖЕНИЕ Б

Фрагмент программы для вывода изображения аналоговых сигналов

.DSEG

;------------------------------------------------------------

TaktCounter: .BYTE 1 ;Для подсчета тактов таймера на один сдвиг

SignCounter: .BYTE 1 ;Для указания на кривые

;Графические каналы:

.EQU ChYb = 0 ;Координата верхней строки (2 байта)

.EQU ChYbH = 1 ;Координата верхней строки (старш. байт)

.EQU ChData = 2 ;Выводимые данные (0-255)

.EQU ChPreY = 3 ;Предыдущая координата Y'(2 байта)

.EQU ChPreYH = 4 ;Предыдущая координата (старш. байт)

.EQU ChPre1Y = 5 ;Препредыдущая координата Y"(2 байта)

.EQU ChPre1YH = 6 ;Препредыдущая координата (старш. байт)

.EQU ChColor = 7 ;Цвет канала

.EQU ChStatus = 8 ;Состояние канала (0-норма;1-вывод сообщения; 2-ничего)

.EQU ChFlags = 9 ;Флаги

.EQU ChMsg = 10 ;Номер сообщения для канала

.EQU ChMsgCnt = 11 ;Счетчик выведенных столбцов сообщения

.EQU CH_SZ_Y = 128 ;(Ширина каналов - 128 точек)

.EQU NUM_FLD_CH = 5 ;Количество каналов

.EQU BYTE_FLD_CH = 12 ;Количество данных/канал

Chanals: .BYTE NUM_FLD_CH*BYTE_FLD_CH ;область данных каналов

;******************************************************

.CSEG

;****************************************************

;Подпрограмма отрисовки канала.

;Параметры:

.def CHAN_NUM = r2 ;Номер отрисовываемого канала

DrawChanal:

push YH

push YL

push r25

push r24

push r16

push r11

push r10

push r9

push r8

push r7

push r6

push r5

push r4

push r3

push r2

push r1

push r0

ldi YL,low(Chanals) ;Y - 1-й канал

ldi YH,high(Chanals)

ldi r16,BYTE_FLD_CH

mul CHAN_NUM,r16

add YL,r0

adc YH,r1 ;Y - CHAN_NUM-й канал

ldd r16,Y+ChStatus

cpi r16,0

breq DrawChs

jmp DrawMsg

DrawChs:

;Вычисление координат последней точки:

; ChPreY = ChYb+CH_SZ_Y-ChData/2

ldd r4,Y+ChYb

ldd r5,Y+ChYbH

movw r0,r4 ;Рисование верхней координатной линии

ldi r16,SetLineFrom

rcall VideoService

ldi r16,1

mov r0,r16

clr r1

ldi r16,0b00010101

mov r2,r16

ldi r16,DrawLineTo

rcall VideoService;--------------------------------

ldi r16,CH_SZ_Y

add r4,r16

ldi r16,0

adc r5,r16 ;ChYb+CH_SZ_Y

movw r0,r4 ;Рисование нижней координатной линии

ldi r16,SetLineFrom

rcall VideoService

ldi r16,1

mov r0,r16

clr r1

ldi r16,0b00010101

mov r2,r16

ldi r16,DrawLineTo

rcall VideoService;--------------------------------

ldd r3,Y+ChData

lsr r3 ; ChData/2

sub r4,r3 ;младш.байт Y

ldi r16,0

sbc r5,r16 ;старш.байт Y

ldd r6,Y+ChPreY ;Y'

ldd r7,Y+ChPreYH

ldd r8,Y+ChPre1Y ;Y"

ldd r9,Y+ChPre1YH

;Формирование флагов отношений

movw r0,r8 ;Y"<Y'

sub r0,r6

sbc r1,r7

brge geM0

sbr r16,0b100

geM0:

movw r0,r6 ;Y'<Y

sub r0,r4

sbc r1,r5

brge geM1

sbr r16,0b010

geM1:

movw r0,r8 ;Y"<Y

sub r0,r4

sbc r1,r5

brge geM2

sbr r16,0b001

geM2:

;Выбор начала линии

mov r3,r16

andi r16,0b011

cpi r16,0

brne nxtCpi

movw r24,r4 ;Начало - Y

;adiw r24,1

rjmp SetBeg

nxtCpi:mov r16,r3

andi r16,0b110

cpi r16,0b010

brne nxtCpi2

movw r24,r6 ;Начало - Y'

rjmp SetBeg

nxtCpi2:movw r24,r8 ;Начало - Y"

;adiw r24,1

SetBeg:movw r10,r24

movw r0,r24

ldi r16,SetLineFrom ;Установить начало линии

rcall VideoService

;Выбор конца линии

mov r16,r3

andi r16,0b011

cpi r16,0b011

brne nxtCpi3

movw r24,r4 ;Конец - Y

;sbiw r24,1

rjmp SetEnd

nxtCpi3:mov r16,r3

andi r16,0b110

cpi r16,0b100

brne nxtCpi4

movw r24,r6 ;Конец - Y'

rjmp SetEnd

nxtCpi4:movw r24,r8 ;Конец - Y"

;sbiw r24,1

SetEnd:sub r24,r10 ;Длина линии (Кон-Нач)

sbc r25,r11

cpi r24,2

brge ncorr

ldi r24,2 ;Если длина<2,то увелич до 2

clr r25

ncorr: movw r0,r24

ldd r2,Y+ChColor ;цвет линии

ldi r16,DrawLineTo ;Отрисовать линию

rcall VideoService

std Y+ChPreY,r4 ;Y'=Y

std Y+ChPreYH,r5

std Y+ChPre1Y,r6 ;Y"=Y'

std Y+ChPre1YH,r7

DrawMsg:pop r0

pop r1

pop r2

pop r3

pop r4

pop r5

pop r6

pop r7

pop r8

pop r9

pop r10

pop r11

pop r16

pop r24

pop r25

pop YL

pop YH

ret

;---------------------------------------------

.EQU TAKT_SHIFT = 1 ;На сколько тактов таймера один сдвиг

;Обработка прерывания от таймера

TimerInt:

push r0

push r1

push r2

push r3

push r16

push YL

push YH

push ZL

push ZH

ldi YL,low(Chanals) ;Y - 1-й канал

ldi YH,high(Chanals)

;ldi r16,BYTE_FLD_CH

;mov r0,r16

;clr r1

lds r2,SignCounter

clr r3

ldi ZL,low(Sign1<<1)

ldi ZH,high(Sign1<<1)

add ZL,r2

adc ZH,r3

lpm r16,Z ;Загрузка из прогр-й памяти кривой

std Y+ChData,r16 ;Данные 1-го канала

;add YL,r0

;adc YH,r1

adiw YL,BYTE_FLD_CH

ldi ZL,low(Sign2<<1)

ldi ZH,high(Sign2<<1)

add ZL,r2

adc ZH,r3

lpm r16,Z ;Загрузка из прогр-й памяти кривой

std Y+ChData,r16 ;Данные 2-го канала

adiw YL,BYTE_FLD_CH

ldi ZL,low(Sign1<<1)

ldi ZH,high(Sign1<<1)

add ZL,r2

adc ZH,r3

lpm r16,Z ;Загрузка из прогр-й памяти кривой

std Y+ChData,r16 ;Данные 3-го канала

adiw YL,BYTE_FLD_CH

adiw YL,BYTE_FLD_CH

ldi ZL,low(Sign3<<1)

ldi ZH,high(Sign3<<1)

add ZL,r2

adc ZH,r3

lpm r16,Z ;Загрузка из прогр-й памяти кривой

std Y+ChData,r16 ;Данные 5-го канала

lds r16,SignCounter

inc r16

cpi r16,100

brne lbl11

clr r16

lbl11: sts SignCounter,r16

lds r2,TaktCounter

dec r2

sts TaktCounter,r2

brne NShift

ldi r16,TAKT_SHIFT

sts TaktCounter,r16

ldi r16,ShiftArea ;Сдвинуть область

rcall VideoService

ldi r16,low(ShftYdn-ShftYup)

mov r0,r16

ldi r16,high(ShftYdn-ShftYup)

mov r1,r16

clr r2 ;цвет линии

ldi r16,DrawLineTo ;Отрисовать черную линию

rcall VideoService

clr r16

DrAllCh:mov CHAN_NUM,r16

rcall DrawChanal

inc r16

cpi r16,NUM_FLD_CH

brne DrAllCh

NShift: pop ZH

pop ZL

pop YH

pop YL

pop r16

pop r3

pop r2

pop r1

pop r0

reti

Размещено на Allbest.ru